Arama ve başvuru · Excel fonksiyonu

Excel ÇAPRAZARA formülü

Türkçe Excel: ÇAPRAZARAİngilizce Excel: XLOOKUPMicrosoft 365 ve Excel 2021 ile gelir

ÇAPRAZARA, bir değeri bir sütunda arar ve başka bir sütunun aynı satırındaki değeri getirir. DÜŞEYARA fonksiyonundan farkı, aranan ve getirilen sütunu ayrı ayrı seçmendir: sütun numarası saymazsın, getirilecek sütun aranan sütunun solunda da olabilir ve varsayılan olarak tam eşleşme yapılır.

İngilizce Excel'de adı XLOOKUP. Microsoft 365 ve Excel 2021 ile gelmiştir; Excel 2019 ve önceki sürümlerde bulunmaz.

ÇAPRAZARA nasıl yazılır?

Türkçe Excel=ÇAPRAZARA(aranan_değer; aranan_dizi; döndürülen_dizi; [bulunamazsa])

İngilizce Excel=XLOOKUP(lookup_value, lookup_array, return_array, [if_not_found])

aranan_değer: Aradığın değer ya da hücre.
aranan_dizi: Aramanın yapılacağı sütun (ya da satır).
döndürülen_dizi: Sonucun alınacağı sütun. Aranan diziyle aynı boyda olmalı.
bulunamazsa: İsteğe bağlı. Değer bulunamazsa #YOK yerine gösterilecek değer: "Kayıt yok".

Köşeli parantez içindeki argümanlar isteğe bağlıdır. Excel'de iki isteğe bağlı argüman daha vardır: eşleştirme modu (joker karakterle ya da yaklaşık arama için) ve arama modu (sondan başa doğru arama için). Günlük işlerin çoğunda ilk dört argüman yeter.

ÇAPRAZARA örnekleri

Formüller aşağıdaki tabloya göre yazıldı; sonuçlar Hücre'nin formül motoruyla hesaplandı.

	A	B	C	D
1	Ad Soyad	Sicil	Departman	Dahili
2	Hakan Çelik	1001	Satış	214
3	Gizem Aksoy	1002	Muhasebe	308
4	Onur Polat	1003	Satış	219
5	Büşra Kurt	1004	İK	402

Rehber

=ÇAPRAZARA(1003;B2:B5;A2:A5)Onur Polat
Sicil B sütununda aranır, ad soldaki A sütunundan getirilir. DÜŞEYARA ile bu yapılamaz.
İngilizce Excel'de: =XLOOKUP(1003,B2:B5,A2:A5)
=ÇAPRAZARA("Büşra Kurt";A2:A5;D2:D5)402
Ada göre dahili numarayı getirir; sütun numarası saymak gerekmez.
İngilizce Excel'de: =XLOOKUP("Büşra Kurt",A2:A5,D2:D5)
=ÇAPRAZARA(1009;B2:B5;A2:A5;"Kayıt yok")Kayıt yok
Dördüncü argüman sayesinde bulunamayan değer için #YOK yerine kendi mesajın görünür.
İngilizce Excel'de: =XLOOKUP(1009,B2:B5,A2:A5,"Kayıt yok")

Kendin dene: ÇAPRAZARA alıştırması

Formülü tablodaki kesik çizgili hücreye yaz ve Enter'a bas. Hücre sonucu kontrol eder, yanlışsa nedenini söyler. Kayıt gerekmez.

Sık yapılan hatalar

Eski bir Excel sürümünde kullanmak

ÇAPRAZARA Excel 2019 ve öncesinde yoktur; dosyayı eski sürümde açan kişi #AD? hatası görür. Dosyayı paylaşacağın kişilerin sürümünden emin değilsen İNDİS ile KAÇINCI kullan.

Aralıkların boyunu farklı seçmek

Aranan dizi ile döndürülen dizi aynı sayıda satır içermeli. C2:C6 ile A2:A7 birlikte kullanılırsa #DEĞER! hatası çıkar.

$ işaretini unutmak

Formülü aşağı dolduracaksan iki aralığı da sabitle: $C$2:$C$6 ve $A$2:$A$6. Yoksa aralıklar kayar ve üst satırlardaki değerler bulunamaz.

Virgül kullanmak

İngilizce kaynaklardaki =XLOOKUP(E2,C2:C6,A2:A6) Türkçe Excel'de =ÇAPRAZARA(E2;C2:C6;A2:A6) diye yazılır.

İlgili dersler

Hücre'deki derslerde bu konuyu gerçek tablolarla, adım adım ve anında geri bildirimle çalışırsın.

Sıfırdan başlıyorsan: ilk 20 ders ücretsiz. Hücre seçmekten TOPLA, ORTALAMA ve YUVARLA'ya kadar; kayıt ve kart gerekmez.

Ücretsiz derslere başla