Arama ve başvuru · Excel fonksiyonu

Excel FİLTRE formülü

Türkçe Excel: FİLTREİngilizce Excel: FILTERMicrosoft 365 ve Excel 2021 ile gelir

FİLTRE, bir tablodan koşulu sağlayan satırları alır ve sonucu formülü yazdığın hücreden başlayarak alt alta taşırır. Stoku biten ürünleri, bekleyen görevleri ya da bir müşterinin bütün siparişlerini ayrı bir listede görmek için kullanılır. Asıl tablo değiştikçe liste de kendiliğinden güncellenir.

İngilizce Excel'de adı FILTER. Veri sekmesindeki Filtre düğmesinden farkı, asıl tabloyu gizlemeden sonucu yeni bir yere yazmasıdır.

FİLTRE nasıl yazılır?

Türkçe Excel=FİLTRE(dizi; ekle; [boşsa])

İngilizce Excel=FILTER(array, include, [if_empty])

dizi: Satırları getirilecek tablo ya da sütun: A2:B8.
ekle: Her satır için DOĞRU ya da YANLIŞ üreten koşul: C2:C8="Bekliyor". Tabloyla aynı sayıda satır içermeli.
boşsa: İsteğe bağlı. Hiç satır koşula uymazsa gösterilecek değer: "Kayıt yok".

Köşeli parantez içindeki argümanlar isteğe bağlıdır. İki koşulun birlikte sağlanması için koşullar parantez içinde çarpılır: (B2:B7="Elektronik")*(C2:C7>0). "Ya da" için toplanır.

FİLTRE örnekleri

Formüller aşağıdaki tabloya göre yazıldı; sonuçlar Hücre'nin formül motoruyla hesaplandı.

	A	B	C
1	Ürün	Kategori	Stok
2	Defter	Kırtasiye	140
3	Kalem	Kırtasiye	0
4	Kulaklık	Elektronik	12
5	Dosya	Kırtasiye	35
6	Mouse	Elektronik	0
7	Şarj kablosu	Elektronik	48

Stok

=METİNBİRLEŞTİR(", ";DOĞRU;FİLTRE(A2:A7;C2:C7=0))Kalem, Mouse
FİLTRE stoku 0 olan ürünlerin adlarını getirir. Sayfada tek başına yazılınca sonuçlar alt alta taşar; burada tek satırda görmek için METİNBİRLEŞTİR ile birleştirdik.
İngilizce Excel'de: =TEXTJOIN(", ",TRUE,FILTER(A2:A7,C2:C7=0))
=METİNBİRLEŞTİR(", ";DOĞRU;FİLTRE(A2:A7;(B2:B7="Elektronik")*(C2:C7>0)))Kulaklık, Şarj kablosu
İki koşul çarpılır: kategorisi Elektronik olan ve stokta bulunan ürünler.
İngilizce Excel'de: =TEXTJOIN(", ",TRUE,FILTER(A2:A7,(B2:B7="Elektronik")*(C2:C7>0)))
=FİLTRE(A2:A7;C2:C7>500;"Kayıt yok")Kayıt yok
Stoku 500'ün üstünde ürün olmadığı için hata yerine üçüncü argümandaki metin görünür.
İngilizce Excel'de: =FILTER(A2:A7,C2:C7>500,"Kayıt yok")

Kendin dene: FİLTRE alıştırması

Formülü tablodaki kesik çizgili hücreye yaz ve Enter'a bas. Hücre sonucu kontrol eder, yanlışsa nedenini söyler. Kayıt gerekmez.

Sık yapılan hatalar

#HESAPLA! hatası

Hiçbir satır koşula uymazsa FİLTRE boş bir sonuç döndüremez ve #HESAPLA! verir. Üçüncü argümana bir mesaj yaz: =FİLTRE(A2:B8;C2:C8="İptal";"Kayıt yok").

#TAŞMA! hatası

Sonucun taşacağı hücrelerden biri doluysa Excel sonucu yazamaz ve #TAŞMA! gösterir. Formülün altındaki ve sağındaki hücreleri boşalt; liste uzayabileceği için altında yer bırak.

Koşul aralığının boyunu farklı seçmek

Koşul, tabloyla aynı satırdan başlamalı ve aynı sayıda satır içermeli. A2:B8 ile C2:C9 birlikte kullanılırsa #DEĞER! hatası çıkar.

İki koşulu ; ile yazmak

=FİLTRE(A2:B8;C2:C8="Bekliyor";B2:B8="Ece") iki koşul vermez; üçüncü argüman "bulunamazsa" değeridir. Koşulları parantez içinde çarp: (C2:C8="Bekliyor")*(B2:B8="Ece").

Eski bir Excel sürümünde kullanmak

FİLTRE Excel 2019 ve öncesinde yoktur; dosyayı eski sürümde açan kişi #AD? görür. Paylaşacağın kişilerin sürümünden emin değilsen Veri sekmesindeki Filtre düğmesini kullan.

İlgili dersler

Hücre'deki derslerde bu konuyu gerçek tablolarla, adım adım ve anında geri bildirimle çalışırsın.

Sıfırdan başlıyorsan: ilk 20 ders ücretsiz. Hücre seçmekten TOPLA, ORTALAMA ve YUVARLA'ya kadar; kayıt ve kart gerekmez.

Ücretsiz derslere başla